/*
 ================================================
 Animation of T/I-shaped guide patterns in action
 ------------------------------------------------
 Created by Søren Peo Pedersen - see my user page
 at http://da.wikipedia.org/wiki/Bruger:Peo
 ================================================
 */

 #declare MagnetFont="arialbd.ttf" // Font for the nomenclature on magnets
 #declare NorthLtr="N";  // Letter to indicate north pole
 #declare SouthLtr="S";  // Letter to indicate south pole
 
 #declare TrkPhase=-1+clock;  // Control variable for "phase" of bubble movement
 #declare BubblePos=1.6*TrkPhase-.8-sin(8*pi*TrkPhase)*.05; // Compute bubble position

 box {<-4,-.3,-4>,<4,.3,4> // The orthomagnetic sheet
   pigment {
     object {
       merge {
         cylinder {<BubblePos,-1,2.4>,<BubblePos,1,2.4>,.3}         // with a chain
         cylinder {<BubblePos+1.6,-1,2.4>,<BubblePos+1.6,1,2.4>,.3} // of bubbles
         cylinder {<BubblePos+3.2,-1,2.4>,<BubblePos+3.2,1,2.4>,.3} // moving across
         }
       pigment {color rgb <1,1,1>}  // Simple colors to indicate
       pigment {color rgb <1,0,0>}  // magnetic polarity.
       }
     }
   finish {ambient .5}
   }
 
 #declare GuidePolColor=pigment {  // Define rotating color gradient to indi-
   gradient z                      // cate magnetization of the guide pieces
   color_map {
     [0 color rgb <1,.25,.25>]
     [.45 color rgb .5]
     [.55 color rgb .5]
     [1 color rgb 1]    
     }
   translate -.5
   scale 1.5
   rotate <0,360*TrkPhase-180,0> // Turns clockwise once per phase count
   }
 
 #declare Tguide=merge { // Define shape of "T" guide
   cylinder {<-.5,.3,.5>,<.5,.3,.5>,.03}    // Lots of cylinders and spheres,
   sphere {<.5,.3,.5>,.03}                  // for smooth edges and corners.
   cylinder {<.5,.3,.5>,<.5,.3,.3>,.03}
   sphere {<.5,.3,.3>,.03}
   cylinder {<.5,.3,.3>,<.1,.3,.3>,.03}  
   cylinder {<.1,.3,.3>,<.1,.3,-.5>,.03}
   sphere {<.1,.3,-.5>,.03}
   cylinder {<.1,.3,-.5>,<-.1,.3,-.5>,.03}
   sphere {<-.1,.3,-.5>,.03}
   cylinder {<-.1,.3,.3>,<-.1,.3,-.5>,.03}
   cylinder {<-.5,.3,.3>,<-.1,.3,.3>,.03}
   sphere {<-.5,.3,.3>,.03}
   cylinder {<-.5,.3,.5>,<-.5,.3,.3>,.03}  
   box {<-.5,0,.3>,<.5,.33,.5>}
   box {<-.1,0,-.5>,<.1,.33,.3>}
   pigment {GuidePolColor}        // Colored according to magnitization
   finish {ambient .5 phong 1}
   }
 
 #declare Iguide=merge {    // Defines the I-shaped guide pieces
   cylinder {<-.1,.3,.5>,<.1,.3,.5>,.03}  // More cylinders and spheres for
   sphere {<.1,.3,.5>,.03}                // more smooth edges and corners.
   cylinder {<.1,.3,.5>,<.1,.3,-.5>,.03}
   sphere {<.1,.3,-.5>,.03}
   cylinder {<.1,.3,-.5>,<-.1,.3,-.5>,.03}  
   sphere {<-.1,.3,-.5>,.03}
   cylinder {<-.1,.3,-.5>,<-.1,.3,.5>,.03}
   sphere {<-.1,.3,.5>,.03}
   box {<-.1,0,-.5>,<.1,.33,.5>}
   pigment {GuidePolColor}        // Colored according to magnetization
   finish {ambient .5 phong 1}
   }
 
 merge {         // The black arrow that indicates the direction
   difference {  // of the collective field from the driving coils
     box {<0,-.001,-1>,<1,.001,0>
       rotate <0,45,0> scale <1,1,3> translate <0,0,.7>}
     plane {<0,0,1>,.1}
     }
   box {<-.05,-.001,-.7>,<.05,.001,.1>}
   pigment {color rgb 0}
   rotate <0,360*TrkPhase,0>  // Rotates once per phase count
   translate <0,0,5.2>
   }
 
 // Render the north pole nomenclature that follows the rotating arrow:
 #declare Nletter=text {ttf MagnetFont,NorthLtr,0,.001 scale .5 rotate <90,0,0>}
 #object {Nletter
   translate <
     (min_extent(Nletter).x-max_extent(Nletter).x)/2-sin(TrkPhase*2*pi)*.95
     0,
     (min_extent(Nletter).z-max_extent(Nletter).z)/2-cos(TrkPhase*2*pi)*.95+5.2>
     }

 // Render the south pole nomenclature that follows the rotating arrow
 #declare Sletter=text {ttf MagnetFont,"S",0,.001 scale .5 rotate <90,0,0>}
 #object {Sletter
   translate <
     (min_extent(Sletter).x-max_extent(Sletter).x)/2+sin(TrkPhase*2*pi)*.95
     0,
     (min_extent(Sletter).z-max_extent(Sletter).z)/2+cos(TrkPhase*2*pi)*.95+5.2>
     }
 
 #local Col=0;  // Loop to draw up a few "T's" and "I's" of a track:
 #while (Col<4)
   #object {Tguide translate <1.6*Col-3.2,0,2>}
   #object {Iguide translate <1.6*Col-2.4,0,2.8>}
   #local Col=Col+1;
 #end
 #object {Tguide translate <3.2,0,2>}
 
 background {color rgb 1} // White background
 
 camera { // Look at the scenario   
   location <0,4,3.7> // from this vantage point,
   look_at <0,0,3.7>  // looking towards this point.
   up <0,4/3,0> right <1,0,0> // Force 4:3 "portrait" aspect.
   }
 
 light_source {     // Illumination
   <-100,150,-120>
   color rgb 1
   }