// Calcul de probabilités de jets de dés par dénombrement

function [frequences]=tirages(nb_d, nb_faces)
    // calcule les fréquences de nb_d tirage de dés par dénombrement
    // entrées :    nb_d : nombre de tirages (entier)
    //              nb_faces : nombre de faces du dé
    // sorties : frequences : matrice de fréquences (réels)
    
    N = nb_faces^nb_d; // nombre de valeurs possibles
    resultats = zeros(N, nb_d); // initialisation : résultats des tirages
    for i = 1:nb_d // n° de colonne
        k = nb_faces^(nb_d - i); //à la colonne i,
        //  on alterne k valeurs 0 et k valeurs 1
        for j=0:nb_faces^(i - 1) - 1
            for jj = 1:nb_faces
                resultats((nb_faces*j + jj - 1)*k + 1:(nb_faces*j + jj)*k, i)...
                = jj;
            end
        end
    end
    //disp(resultats);
    somme = sum(resultats, "c");
    frequences_non_triees = tabul(somme);
    frequences = gsort(frequences_non_triees, "lr", "i");
    frequences(:,2) = 100*frequences(:,2)/N; // normalisation des fréquences
endfunction

// génération des valeurs

freq_1d6 = tirages(1, 6);
freq_2d6 = tirages(2, 6);
freq_3d6 = tirages(3, 6);
freq_4d6 = tirages(4, 6);
freq_5d6 = tirages(5, 6);

freq_cumul_1d6 = freq_1d6;
freq_cumul_1d6(:, 2) = cumsum(freq_1d6(:, 2))
freq_cumul_2d6 = freq_2d6;
freq_cumul_2d6(:, 2) = cumsum(freq_2d6(:, 2))
freq_cumul_3d6 = freq_3d6;
freq_cumul_3d6(:, 2) = cumsum(freq_3d6(:, 2))
freq_cumul_4d6 = freq_4d6;
freq_cumul_4d6(:, 2) = cumsum(freq_4d6(:, 2))
freq_cumul_5d6 = freq_5d6;
freq_cumul_5d6(:, 2) = cumsum(freq_5d6(:, 2))

// Tracé

scf(0);
clf;

cmap = zeros(5, 3);
cmap(:,1) = linspace(0, 0.5, 5)';
cmap(:,2) = cmap(:,1);
cmap(:, 3) = ones(5)';
xset("colormap", cmap)

subplot(2, 1, 1)
plot2d(freq_1d6(:, 1), freq_1d6(:, 2), style=1)
courbe = gce();
courbe.children.mark_style = 1;
courbe.children.mark_foreground = 1;
plot2d(freq_2d6(:, 1), freq_2d6(:, 2), style=2)
courbe = gce();
courbe.children.mark_style = 2;
courbe.children.mark_foreground = 2;
plot2d(freq_3d6(:, 1), freq_3d6(:, 2), style=3)
courbe = gce();
courbe.children.mark_style = 3;
courbe.children.mark_foreground = 3;
plot2d(freq_4d6(:, 1), freq_4d6(:, 2), style=4)
courbe = gce();
courbe.children.mark_style = 4;
courbe.children.mark_foreground = 4;
plot2d(freq_5d6(:, 1), freq_5d6(:, 2), style=5)
courbe = gce();
courbe.children.mark_style = 5;
courbe.children.mark_foreground = 5;

xtitle("Fréquences (probabilité d''avoir une valeur)",...
    "résultat des dés", "probabilité (%)")
legend("1d6", "2d6", "3d6", "4d6","5d6")

subplot(2, 1, 2)
plot2d(freq_cumul_1d6(:, 1), freq_cumul_1d6(:, 2), style=1)
courbe = gce();
courbe.children.mark_style = 1;
courbe.children.mark_foreground = 1;
plot2d(freq_cumul_2d6(:, 1), freq_cumul_2d6(:, 2), style=2)
courbe = gce();
courbe.children.mark_style = 2;
courbe.children.mark_foreground = 2;
plot2d(freq_cumul_3d6(:, 1), freq_cumul_3d6(:, 2), style=3)
courbe = gce();
courbe.children.mark_style = 3;
courbe.children.mark_foreground = 3;
plot2d(freq_cumul_4d6(:, 1), freq_cumul_4d6(:, 2), style=4)
courbe = gce();
courbe.children.mark_style = 4;
courbe.children.mark_foreground = 4;
plot2d(freq_cumul_5d6(:, 1), freq_cumul_5d6(:, 2), style=5)
courbe = gce();
courbe.children.mark_style = 5;
courbe.children.mark_foreground = 5;

xtitle("Fréquences cumulées (probabilité de faire moins qu''une valeur)",...
    "résultat des dés", "probabilité (%)")