#include "colors.inc"
#include "textures.inc"   
#include "glass.inc"
#include "finish.inc"
#include "woods.inc"
#include "stones.inc"

//#include "golds.inc"



#declare Glockenglass = texture { T_Glass3 }

background {rgb<0.1,0.1,0.1>}

//global_settings { ambient_light  rgb<0.1,0.1,0.1> }
global_settings { ambient_light  rgb<1,1,1> }

#declare winkel = 63.43665;
/*
winkel = 61
*/

#declare f = 1.618034;
#declare fusshoehe = 5;
#declare fussradius = 35;

#declare bodenabstand = 1;
#declare wandabstand = 60;
#declare wandbreite = wandabstand *2*tan(72/2 );
//#declare wandbreite = 87.1851;
#declare wandhoehe = 120;
#declare wanddicke =1;
#declare rohrhoehe = 40;
#declare rohrradius = 32;
#declare rohrdicke =0.51;  
#declare kugelradius = 2;
#declare griffradius = 2* kugelradius;
#declare lochradius = 8;
#declare kerbe1radius = lochradius * 1.3;
#declare kerbe2radius = lochradius * 1.5;
#declare dicke = 2;
#declare kerbtiefe = dicke /5.0;
#declare kerbbreite = kerbtiefe;
#declare plattenbreite = 20;
/* dradius = plattenbreite * tan(90-360/5/2) /2  */
#declare dradius = plattenbreite /2 * 1.3763;
#declare tol =1;
#declare pentradius = 2*12.3101-dicke;

#declare zoffset =0;

 

#declare fogfactor=0.0;

/*
camera {
       location <0, -550, 120>
       look_at  <0, 0, 7>    
//       rotate <0,90,0>
       angle 13.5  
                      
       }
       */
camera {
  perspective
       location <0, -550, 120>
       look_at  <0, 0, 7>    
       angle 13.5  
  normal {
    //waves 0.0025 * (1 - clock)
    waves 0
    frequency 8
    phase 3.14 * clock
  }
}
   


// light_source { <-100, 220, -240> color White}  
  light_source { <-80, -200, 300> color White
  spotlight
  point_at <10,10,10>    
  falloff 80
  radius 90
  
  
  }
  
  light_source { <-90, -150, 10> color White
  spotlight
  point_at <-2*rohrradius,10,50>    
  falloff 80
  radius 90
  }

  light_source { <80, -200, 200> color White
  spotlight
  point_at <2*rohrradius,23,-pentradius-kugelradius>    
  falloff 40
  radius 60
  }


  light_source { <80, -200, 200> color White
  spotlight
  point_at <rohrhoehe,23,rohrhoehe>    
  falloff 40
  radius 60
  }


/*
  light_source 
        { 
        <0, 400, 120> 
        color White
        area_light <0, 400, 120>, <110, 400, 120>, 5, 5
        adaptive 1
        jitter
        }
*/



                                
	#declare kerbe1=difference {
	cylinder {
	<0,0,-pentradius-tol> <0,0,-pentradius+kerbtiefe>
	kerbe1radius
	}	
	
	cylinder  {
	<0,0,-pentradius-tol> <0,0,-pentradius+kerbtiefe>
	kerbe1radius-kerbbreite
	}	

	}

	#declare kerbe2=difference {
	cylinder {
	<0,0,-pentradius-tol> <0,0,-pentradius+kerbtiefe>
	kerbe2radius
	}	
	cylinder  {
	<0,0,-pentradius-tol><0,0,-pentradius+kerbtiefe>
	kerbe2radius-kerbbreite
	}	
	}




	#declare platte = box {
	<-plattenbreite /2, 0,-pentradius>
	<plattenbreite /2, dradius,dicke-pentradius>
	}       
	
	#declare messer = box {
	<-plattenbreite  , 0,-tol-pentradius>
	<plattenbreite , 4*plattenbreite,dicke+tol-pentradius>
	rotate -126*z
	}
	
	#declare  messer2= box {
	<-plattenbreite , 0,-tol-pentradius>
	<plattenbreite , 4*plattenbreite,dicke+tol-pentradius>
	rotate 126*z	
	}
	
	#declare stempel = cylinder {
	<0,0,-tol-pentradius> <0,0,dicke+tol-pentradius>
	lochradius
	}	


#declare fuenfeck = difference
                        {
                            difference
                            {
                                    difference
                                    {
                
                                            difference
                                            {
                                                difference 
                                                { 
                                                object{platte} 
                                                object{messer}
                                                }
                                                object{messer2}
                                            }
                                            object {stempel}
                                    }
                                    object {kerbe1}
                            }
                            object {kerbe2}
                        }





#declare pentagon =   union {
                              object{fuenfeck }
                              object{fuenfeck  rotate 72*z   }
                              object{fuenfeck  rotate 72*2*z }
                              object{fuenfeck  rotate 72*3*z }
                              object{fuenfeck  rotate 72*4*z }
                              finish   {  reflection { 0.4 rgbt<1,1,1,0.9> }  }
                              pigment { Gold filter .1 }

                             }




#declare kugelu=sphere 
        { 
        <plattenbreite /2+4*kugelradius /5,dradius+4*kugelradius /5,-pentradius >,  kugelradius 
        rotate 36*z    
        
          finish  { reflection { 0.4 rgbt<1,1,1,0.6> } }
          pigment { Gold filter .1 }
        }

#declare kugelmo=sphere 
        { 
        <f*plattenbreite /2+4*kugelradius /5,f*dradius+4*kugelradius /5, -pentradius +0.89444*plattenbreite>,  kugelradius 
        rotate 36*z        
          finish  { reflection { 0.4 rgbt<1,1,1,0.6> } }
         pigment { Gold filter .1 }
        }

#declare kugelmu=sphere 
        { 
        <f*plattenbreite /2+4*kugelradius /5,f*dradius+4*kugelradius /5, +pentradius -0.89444*plattenbreite >,  kugelradius 
          finish  { reflection { 0.4 rgbt<1,1,1,0.6> } }
        }

#declare kugelo=sphere 
        { 

        <plattenbreite /2+4*kugelradius /5,dradius+4*kugelradius /5,pentradius  >,  kugelradius 
          finish  { reflection { 0.4 rgbt<1,1,1,0.6> } }
          pigment { Gold filter .1 }
        }


#declare pentagon_dodekaeder = union {
object { pentagon rotate 36*z }
object { pentagon scale<1,-1,1> rotate winkel*x  rotate(36+72)*z }
object { pentagon scale<1,-1,1> rotate winkel*x  rotate(36+2*72)*z }
object { pentagon scale<1,-1,1> rotate winkel*x  rotate(36+3*72)*z }
object { pentagon scale<1,-1,1> rotate winkel*x  rotate(36+4*72)*z }
object { pentagon scale<1,-1,1> rotate winkel*x  rotate(36+5*72)*z }


object { pentagon  scale<1,1,-1>  }
object { pentagon  scale<1,1,-1> rotate winkel*x rotate (36+72)*z }
object { pentagon  scale<1,1,-1> rotate winkel*x  rotate (36+2*72)*z }
object { pentagon  scale<1,1,-1> rotate winkel*x  rotate (36+3*72)*z }
object { pentagon  scale<1,1,-1> rotate winkel*x  rotate (36+4*72)*z }
object { pentagon  scale<1,1,-1> rotate winkel*x  rotate (36+5*72)*z }

         #declare i=0;
         #while (i < 5)
             object { kugelo  rotate i*72*z }
             object { kugelmo rotate i*72*z }     
             object { kugelmu rotate i*72*z }
             object { kugelu  rotate i*72*z }     
          #declare i=i+1;
         #end
}                      



//object {pentagon_dodekaeder}
object {pentagon_dodekaeder rotate 72*clock*z}



#declare rohraussen = cylinder  {
	<0,0,0> <0,0,rohrhoehe> rohrradius  
	}   
	
#declare rohrinnen = cylinder  {
	<0,0,-1> <0,0,rohrhoehe+1> rohrradius - rohrdicke
	}

#declare haubeaussen = sphere  {
	<0,0,rohrhoehe>	 rohrradius
	}
#declare haubeinnen = sphere  {
	<0,0,rohrhoehe>	 rohrradius - rohrdicke
	}
#declare griff =sphere  {
	<0,0,rohrhoehe+rohrradius+griffradius-rohrdicke> griffradius
	}            

#declare Glocke=merge 
        {               
        difference { 
                   object { rohraussen} 
                   object { rohrinnen }
                   }
                   
        difference { 
                   difference {
                              union {object {haubeaussen} object {griff}} 
                              object {haubeinnen}
                              } 
                   object {rohraussen}   
                   translate <0,0,-0.1>    // toleranz zum Verschmelzen
                   }              
        texture { Glockenglass} 
	interior{ I_Glass}        
                   
        }

object { Glocke  translate <0,0,-pentradius-kugelradius>}


/* boden  */
#declare boden = cylinder{
	<0,0,0>	<0,0,-1> 3*rohrradius

	translate <0,0,-pentradius-kugelradius-fusshoehe*5/3-bodenabstand>
        finish {Mirror} 

        texture { T_Grnt21 } 
	}


#declare wand=box {
	<-wandbreite /2,+wandabstand,0>
	<wandbreite /2,+wandabstand+wanddicke,wandhoehe>
	translate <0,0,-fusshoehe*5/3-bodenabstand-pentradius-kugelradius>
//	texture { pigment{ rgb <0.90, 0.91, 0.98>} finish{ Metal }}
	texture { pigment{ rgb <0.590, 1, 1>} finish {
                    metallic
                    ambient 0.2
                    diffuse 0.4
                    brilliance 6
                    reflection 0.95
                    phong 0.75
                    phong_size 80}
                 }
	}

object { boden }
//object { wand }
object { wand rotate +36*z }
object { wand rotate -36*z }                    
      
      
      
#declare fuss =         
union{         
        cone {
             <0,0,-fusshoehe>,fussradius
             <0,0, 0>, fussradius*0.9
             }
        cylinder {         // fussoben
                 <0,0,0>
                 <0,0,fusshoehe*2/3>
                 rohrradius-0.5
                 }
        	color rgb<0.7,0.7,0.7>     
        texture { T_Wood4}	
     }


object {fuss  translate <0,0,-pentradius-kugelradius-fusshoehe*2/3> }





#declare schenkel= cylinder {<0,0,5> <0,5,15> 0.2}
#declare schienbein= cylinder {<0,5,15> <0,20,0> 0.2}

#declare bein= union { object{schenkel}  object{schienbein}}

 

#declare spinne = union {
sphere  { <-1,0,3> 1 scale <4,3,2> }   // Rumpf
sphere { <1,0,5> 1	scale< 1.5, 1, 1.0> }  // Kopf
sphere { <2.5,1,5> 0.5}                        // Augen
sphere { <2.5,-1,5> 0.5}

object {bein rotate 15*z }
object {bein rotate -15*z }
object {bein rotate 30*z }
object {bein rotate -30*z }
object {bein scale<1,-1,1>  rotate 15*z }
object {bein scale<1,-1,1>  rotate -15*z }
object {bein scale<1,-1,1>  rotate 30*z }
object {bein scale<1,-1,1>  rotate -30*z }

}


object { spinne 
        rgb <1.0,0.9,0.8>
	scale <0.4,0.4,0.4>
	texture {Bright_Bronze}
//	scale <3,3,3>	
	translate <0,-23,-pentradius-kugelradius>
	rotate -45*z
       }


object { spinne 
        rgb <0.8,0.9,1.0>
	scale <0.3,0.3,0.3>
	texture {Bright_Bronze}
//	scale <3,3,3>	
	translate <0,-23,-pentradius-kugelradius>
	rotate 45*z
       }


object { spinne 
        rgb <0.9,0.9,0.9>
	scale <0.2,0.2,0.2>
	texture {Bright_Bronze}
//	scale <3,3,3>	
	translate <0,-23,-pentradius-kugelradius>
	rotate z
       }


object { spinne 
        rgb <0.9,0.9,0.9>
	scale <0.8,0.8,0.8>
//	scale <3,3,3>	
	texture {Bright_Bronze}
//	scale <3,3,3>	
	translate <0,0,-pentradius>
 	rotate -60*z
       }