# Terminal
set terminal svg enhanced size 800 600 font "sans"
set output "greece-tv-viewings-early-90s.svg"
# Data and formats
set datafile missing "-"
set datafile separator whitespace
set xdata time
set timefmt "%Y-%m"
set format x "%Y"
# Scale and ranges
set autoscale
set xrange ["1989-04":"1993-08"]
set yrange [0:50]
# Ticks, borders and title
set border 0
set xtics ("1989","1989","1990","1991","1992","1993", "1994") nomirror
set ytics autofreq nomirror
set grid xtics linetype 1 linewidth 1 linecolor rgb "#efefef"
set grid ytics linetype 1 linewidth 1 linecolor rgb "#efefef"

## Inline data
# Note that months are a little by convention
$data << EOData
1989-09 37.7 24.3    -    - 14.2  10.3  13.5
1989-12 21.1 12.6 35.3    - 10.7   5.8   8.5
1990-06 19.7  8.7 30.6 18.5  5.3   4.7  12.5
1991-06 14.0  6.9 30.9 27.4  3.3   4.0  13.3
1992-06 10.5  5.9 33.6 30.5  1.3   3.6  14.7
1993-06  7.9  5.3 33.2 30.9  1.5   2.8  18.4
# year   et1  et2 mega ant1  sat video other
EOData

plot $data using 1:2 with lines lw 2.5 linecolor rgb "#e41a1c" title "ΕΤ1",    \
     $data using 1:3 with lines lw 2.5 linecolor rgb "#377eb8" title "ΕΤ2",    \
     $data using 1:4 with lines lw 2.5 linecolor rgb "#4daf4a" title "Mega",   \
     $data using 1:5 with lines lw 2.5 linecolor rgb "#984ea3" title "Ant1",   \
     $data using 1:6 with lines lw 2.5 linecolor rgb "#ff7f00" title "Δορυφ.", \
     $data using 1:7 with lines lw 2.5 linecolor rgb "#ffff33" title "Βίντεο", \
     $data using 1:8 with lines lw 2.5 linecolor rgb "#a65628" title "Άλλα"

##