# Graphs of errors for the EU “estimated sign”

# Set terminal
set terminal svg enhanced size 300 300 fs 10
set samples 1001  # high quality
set border 31 linewidth .3 # thin border
unset key # no key

# Tolerable error function:
#  input is nominal quantity
#  output is tolerable negative error, as an absolute quantity
# 
# e(x)/x is thus tolerable ~relative~ error
#
e(x) = x <   50 ?   9e-2 * x  \
     : x <  100 ?        4.5  \
     : x <  200 ? 4.5e-2 * x  \
     : x <  300 ?        9    \
     : x <  500 ?   3e-2 * x  \
     : x < 1000 ?       15    \
     :            1.5e-2 * x     

# X-range and x-tics

# Set x tics at the cutoff points
set xtics ("" 5, "" 50, "100" 100, "200" 200, "300" 300, "500" 500, "1000" 1000)

# Set representative x-range:
#  undefined below 5, and
#  extending above 1500 to 10,000 just shrinks the interesting part of the graph
# 
# (A log-scale on the x-axis would fit everything in, but obscure the linearity
#  in the absolute error; it would be ok in the relative error though.)
set xrange [5:1500]

# Draw the x grid, to show ranges
set grid x

####################
# Absolute error
####################

# Set y tics at the fixed amounts
set ytics (4.5,9,15)

# Set y-range to go from 0 to max (over this x-range)
set yrange [0:22.5]

set output "eu-estimation-tolerance-absolute.svg"
plot e(x)

####################
# Relative error
####################

# Set y-tics at the fixed percentages
set ytics (1.5, 3, 4.5, 9)

# Set y-range (0% – 10%) to include all percentages, with clearance for 9%.
set yrange [0:10]
set format y "%g %%" # Format as percentage

set output "eu-estimation-tolerance-relative.svg"
# Multiply by 100 so as a percentage
plot e(x)/x*100