// Ce script nécessite le module Atoms CASCI

clear;
clf;
// paramètres de la loi de Weibull

beta_forme = 0.845;
eta_echelle = 126;

// génération des données

Y = linspace(0, 1, 30)
Y = Y(2:$-1);

t_orig = floor(idfweibull(Y, beta_forme, eta_echelle))';

t = [2, 5, 9, 13, 17, 22, 27, 39, 39, 39, 52, 64, 64, 76, 86, 97, 108, 121,...
   135, 151, 169, 191, 215, 245, 282, 332]';
t_complet = [t ; 365 ; 365];
N0 = 28

// nombre cumulé

i = 1;
j = 1
n0 = 1;
nt = size(t, "*");
while i < nt
    if t(i)<>t(i+1) then
        D(j) = n0; n0 = 1;
        tt(j) = t(i);
        j = j + 1;
    else
        n0 = n0 + 1;
    end
    i = i+1;
end
D(j) = n0;
tt(j) = t(i);

ndn = j;

n(1) = D(1);
for i = 2:ndn
    n(i) = n(i-1) + D(i); // systèmes défaillants sur l'intervalle
end

N = [N0 ; N0 - n(1:$-1)]; // systèmes en service en entrée d'intervalle

// Probabilités conditionnelles

P = D./N;

// Fiabilité

for i = 1:ndn
    R(i)=prod(1-P(1:i));
end

// tracé

scf(0);
clf;

// plot(tt, R, "--")
plot2d2([0 ; tt], [1 ; R]);
xtitle("Courbe de survie par la méthode de Kaplan-Meier", "t (j)", "R")