קובץ:ConcaveFocalLength.png
לקובץ המקורי (1,280 × 1,024 פיקסלים, גודל הקובץ: 170 ק"ב, סוג MIME: image/png)
זהו קובץ שמקורו במיזם ויקישיתוף. תיאורו בדף תיאור הקובץ המקורי (בעברית) מוצג למטה. |
יש ליצור מחדש את התמונה physical הזו באמצעות גרפיקה וקטורית כדוגמת קובץ SVG. לפעולה זו מספר יתרונות, כפי שניתן לקרוא (באנגלית) בדף Commons:Media for cleanup. אם ברשותכם קובץ SVG, אנא העלו אותו. לאחר מכן, החליפו תבנית זו בתבנית
{{vector version available|שם הקובץ.svg}} |
תקציר
Shows how the geometry of lightbeams going through a concave, spherical lens from left to right, points out the focal point and hence the focal length of that lens.
רישיון
- הנכם רשאים:
- לשתף – להעתיק, להפיץ ולהעביר את העבודה
- לערבב בין עבודות – להתאים את העבודה
- תחת התנאים הבאים:
- ייחוס – יש לתת ייחוס הולם, לתת קישור לרישיון, ולציין אם נעשו שינויים. אפשר לעשות את זה בכל צורה סבירה, אבל לא בשום צורה שמשתמע ממנה שמעניק הרישיון תומך בך או בשימוש שלך.
- שיתוף זהה – אם תיצרו רמיקס, תשנו, או תבנו על החומר, חובה עליכם להפיץ את התרומות שלך לפי תנאי רישיון זהה או תואם למקור.
POV-Ray code
This image was rendered using POV-Ray for Windows version 3.6 and the scene description code below. Note that the POV-Ray installation needs to have access to the font file "timesbi.ttf" for rendering the bold italic "f" in the image.
Show source code |
---|
/*
================================================
Demonstrating focal length for a concave lens
------------------------------------------------
Created by Søren Peo Pedersen - see my user page
at http://da.wikipedia.org/wiki/Bruger:Peo
================================================
*/
#declare LR=5.5; // Radii in lens
#declare IndexOfRefraction=1.66; // Simulated index of refraction
#declare VisF=1; // Show "f" annotation? 0=no, any other number=yes
#declare LineWidth=0.02; //
#declare FL=1/(IndexOfRefraction-1)/(2/LR);
#declare LS=LR+.05;
#macro DashedLine(L)
union {
#local cnt=0;
#while (cnt<L)
box {<-.03,cnt/2,-.02>,<.03,cnt/2+.25,-.021>}
#local cnt=cnt+1;
#end
}
#end
#macro Beam(Shift)
#local pX1=sqrt(LR*LR-Shift*Shift)-LS;
#local VI1=asin(Shift/LR);
#local VO1=asin(Shift/LR*IndexOfRefraction);
#local LLa=-tan(VI1-VO1);
#local LLb=(Shift-LLa*pX1);
#local pX2=pX1+1;
#local pY2=Shift+LLa;
#local ALa=1+LLa*LLa;
#local ALb=(-2*LS+2*LLa*LLb);
#local ALc=LS*LS+LLb*LLb-LR*LR;
#local ALD=ALb*ALb-4*ALa*ALc;
#local pX2=(-ALb-sqrt(ALD))/(2*ALa);
#local pY2=sqrt(LR*LR-(pX2-LS)*(pX2-LS))*select(LLa,-1,1,1);
#local Vud=atan(pY2/(pX2+LS));
#local VI2=Vud+VI1-VO1;
#local VO2=asin(sin(VI2)*IndexOfRefraction);
#local DIR=Vud+VO2;
#local pX3=pX2+50*cos(DIR);
#local pY3=pY2+50*sin(DIR);
union {
sphere_sweep {
linear_spline,4,
<-50,Shift,0>,LineWidth
<pX1,Shift,0>,LineWidth
<pX2,pY2, 0>,LineWidth
<pX3,pY3, 0>,LineWidth
pigment {color rgb<1,.95,.8>}
finish {ambient 1 diffuse 0}
no_shadow no_reflection
translate <0,0,-LineWidth>
scale <1,1,.5>
}
cylinder {0,<0,1000,1>,LineWidth
pigment {
gradient y
color_map {
[0.0 color rgbft <1,.95,.8,0,.6>]
[0.5 color rgbft <1,.95,.8,0,.6>]
[0.5 color rgbft <1,.95,.8,0,1>]
[1.0 color rgbft <1,.95,.8,0,1>]
}
scale .5
}
finish {ambient 1 diffuse 0}
no_shadow no_reflection
rotate <0,0,90+DIR*180/pi>
translate <pX2,pY2,-LineWidth>
scale <1,1,.5>
}
}
#end
#if (VisF != 0) // Include annotation of "f" length in image?
union {
#object {DashedLine(11) translate <0,-2.8,0>}
#object {DashedLine( 7) translate <pi/LR-FL,-2.8,0>}
text {ttf "timesbi.ttf"
"f",.1,0
translate <(pi/LR-FL)/2-.3,-3,0>
}
triangle {<0,-2.7,0>,<-.5,-2.5,0>,<-.5,-2.9,0>}
box {<-.5,-2.66,.001>,<(pi/LR-FL)/2+.3,-2.74,0>}
triangle {<pi/LR-FL,-2.7,0>,<.5+pi/LR-FL,-2.5,0>,<.5+pi/LR-FL,-2.9,0>}
box {<.5+pi/LR-FL,-2.66,.001>,<(pi/LR-FL)/2-.3,-2.74,0>}
pigment {color rgb 1} finish {ambient 1 diffuse 0}
}
#end
difference { // The lens itself
cylinder {<-LS,0,0>,<LS,0,0>,2.3}
sphere {<-LS,0,0>,LR}
sphere {< LS,0,0>,LR}
plane {<0,0,1>,0}
pigment {color rgbt <.8,1,.9,.7>}
finish {phong 1 reflection .1 ambient .5}
interior {ior IndexOfRefraction}
}
#object {Beam( 2.0)} // Beams: The number
#object {Beam( 1.5)} // in parenthesis are
#object {Beam( 1.0)} // the Y coordinates
#object {Beam( 0.5)} // for each beam of
#object {Beam( 0)} // light coming in
#object {Beam(-0.5)} // from the left
#object {Beam(-1.0)}
#object {Beam(-1.5)}
#object {Beam(-2.0)}
camera {
location <-FL/2,-.5,-500>
look_at <-FL/2,-.5,0>
angle 1
}
light_source {<100,100,-100> color rgb 1}
|
פריטים שמוצגים בקובץ הזה
מוצג
concave lens אנגלית
image/png
173,984 בית
1,024 פיקסל
1,280 פיקסל
היסטוריית הקובץ
ניתן ללחוץ על תאריך/שעה כדי לראות את הקובץ כפי שנראה באותו זמן.
תאריך/שעה | תמונה ממוזערת | ממדים | משתמש | הערה | |
---|---|---|---|---|---|
נוכחית | 16:19, 2 במרץ 2006 | 1,024 × 1,280 (170 ק"ב) | Peo~commonswiki | Shows how the geometry of lightbeams going through a concave, spherical lens from left to right, points out the focal point and hence the focal length of that lens. |
שימוש בקובץ
אין בוויקיפדיה דפים המשתמשים בקובץ זה.
שימוש גלובלי בקובץ
אתרי הוויקי השונים הבאים משתמשים בקובץ זה:
- שימוש באתר da.wikipedia.org
מטא־נתונים
קובץ זה מכיל מידע נוסף, שכנראה הגיע ממצלמה דיגיטלית או מסורק שבהם הקובץ נוצר או עבר דיגיטציה.
אם הקובץ שונה ממצבו הראשוני, כמה מהנתונים להלן עלולים שלא לשקף באופן מלא את הקובץ הנוכחי.
התאריך והשעה של שינוי הקובץ | 13:17, 2 במרץ 2006 |
---|