clear;

// balayage vertical
Ty=20; // période balayage
ay1=1/18.4; // pente du signal triangulaire montant
ay2=1/1.6; // pente du signal triangulaire descendant

// balayage horizontal
Tx=0.064; // période balayage
ax1=1/0.057; // pente du signal triangulaire montant 
ax2=1/0.007; // pente du signal triangulaire descendant 

tmin=0;
pas=0.01;
tmax=Ty+0.1; 

function [y]=fy(t)
   n = int(t/Ty);
   T0 = Ty*n;
   T1 = T0+18.4;
   if t <= T1 then
      y = ay1*(t-T0);
      else y = 1-ay2*(t-T1);
   end
endfunction

function [x]=fx(t)
   n = int(t/Tx);
   T0 = Tx*n;
   T1 = T0+0.057;
   if t <= T1 then
      x = ax1*(t-T0);
      else x = 1-ax2*(t-T1);
   end
endfunction

T=tmin:pas:tmax; // période

Y = feval(T,fy);
X = feval(T,fx);

clf;
scf(1);
subplot(2,1,1)
plot2d(T,Y,rect=[tmin,0,tmax,1],style=2)
xtitle('Signal de balayage vertical','t (ms)', 'tension (éch. arbitraire)')

subplot(2,1,2)
plot2d(T,X,rect=[tmin,0,tmax,1],style=2)
xtitle('Signal de balayage horizontal','t (ms)', 'tension (éch. arbitraire)')

xs2gif(1,'balayage_entrelace_signal_bobines_1_periode.gif');